<xsl:fallback>  
Définit un modèle à utiliser lorsqu'un élément de l'extension est introuvable.
 
Catégorie

Instruction
 
Attributs obligatoires

Aucun.
 
Attributs facultatifs

Aucun.
 
Contenu

Un modèle XSLT.
 
Apparaît dans

<xsl:fallback> apparaît dans un modèle.
 
Défini dans

XSLT section 15, Traitement de secours.
 
Exemple

La feuille de style suivante utilise <xsl:fallback> pour terminer la transformation si un élément de l'extension est introuvable :

<?xml version="1.0"?>
<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:db="xalan://DatabaseExtension"
  extension-element-prefixes="db">

  <xsl:output method="html"/>

  <xsl:template match="/">
    <html>
      <head>
        <title><xsl:value-of select="report/title"/></title>
      </head>
      <body>
        <h1><xsl:value-of select="report/title"/></h1>
        <xsl:for-each select="report/section">
          <h2><xsl:value-of select="title"/></h2>
          <xsl:for-each select="dbaccess">
            <db:accessDatabase>
              <xsl:fallback>
                <xsl:message terminate="yes">
                  Database library not available!
                </xsl:message>
              </xsl:fallback> 
            </db:accessDatabase>
          </xsl:for-each>
        </xsl:for-each>
      </body>
    </html>
  </xsl:template>

</xsl:stylesheet>

Lorsque cette feuille de style est utilisée pour transformer un document, l'élément <xsl:fallback> est traité si l'élément de l'extension est introuvable :


Database library not available!

Processing terminated using xsl:message

Dans ce cas, l'élément de l'extension correspond à la classe Java DatabaseExtension. Si, pour quelque raison que ce soit, cette classe ne peut être chargée, l'élément <xsl:fallback> est traité. L'élément <xsl:fallback> n'est traité que lorsque l'élément de l'extension est introuvable ; si le code implémentant cet élément de l'extension est trouvé mais échoue, il faut trouver une autre manière de le gérer. Le format exact du message et la terminaison de la feuille de style par commande varieront également d'un processeur XSLT à l'autre.